ExcelVBA.Net sitesine katkıda bulunabilirsiniz

[düşünceli]

Selamlar,

A1 ve b1 hücrelerinde bulunan değişken olan rakamları, örneğin; c1 hücresinde 2+22=24 şeklinde göstermek mümkün müdür acaba?

Rakamlar, sadece örnekleme için verdiğim rakamlardır. Hücrelerde hangi rakamlar var ise toplama işlemini 5+14=19 şeklinde yapacak c1 hücresinde 5+14=19 şeklinde gösterecek. Böyle Bir kod düzenlenebilir mi sizce?

[Tarkan VURAL]

Merhaba, kodlanarak yapılabilir. A ve B sütunlarına sayılar yazarak kodu çalıştırın.

Kod: Tümünü seç

Sub ToplaFormulGoster()
For i = 1 To Range("a65536").End(3).Row
Cells(i, "c").Value = Cells(i, "a").Value & " + " & Cells(i, "b").Value & " = " & Cells(i, "a").Value + Cells(i, "b").Value
Next i
End Sub

Kullanıcı tanımlı fonksiyon için (Module içine yazınız);

Kod: Tümünü seç

Function ToplaFormulGoster(ByVal ilksayi As Double, ByVal ikincisayi As Double) As String
ToplaFormulGoster = CStr(ilksayi) & " + " & CStr(ikincisayi) & " = " & CStr(ilksayi + ikincisayi)
End Function

A ve B sütunlarında sayi olduğunu varsayarak sonuç sütunundaki ilgili hücre içine ;

Kod: Tümünü seç

=ToplaFormulGoster(A1;B1)

[düşünceli]

Tarkan Bey, çok teşekkür ediyorum. Ellerinize sağlık.

Şu sorumunda cevabı var mı acaba;
Aynı zamanda; F Sütununda rakam girdikçe D sütununda ki (formül sonucunun döndürüldüğü) sayıdan " < "yada "=" olması durumunda birinci sayıdan " >" olması durumunda artan kısmın ikinci sayıdan eksiltmesini sağlayabilirmiyim.

[düşünceli]

Tarkan Bey, çok teşekkür ediyorum. Ellerinize sağlık.

Şu sorumunda cevabı var mı acaba;
Aynı zamanda; F Sütununda rakam girdikçe D sütununda ki (formül sonucunun döndürüldüğü) sayıdan " < "yada "=" olması durumunda birinci sayıdan " >" olması durumunda artan kısmın ikinci sayıdan eksiltmesini sağlayabilirmiyim.

Yeni konu açmamak için bu konudan devam ettim. Umarım, farklı konu açmadığım için cevapsız kalmaz.

[düşünceli]

Selamlar;
Makro ile B2 ve C2 Hücrelerinde bulunan 2 sayıyı, E2 hücresinde "ToplaFormulGoster(B2;C2)" kodu ile "5+22=27" şeklinde gösterebiliyorum. (Sayın Tarkan Bey sayesinde)

Aynı zamanda; F2 hücresinde rakam girdikçe E2 hücresinde ki (formül sonucunun döndürüldüğü) sayıdan "< " yada "=" olması durumunda birinci sayıdan, " >" olması durumunda ise"artan kısmın ikinci sayıdan" eksiltmesini sağlayabilirmiyim?

Örnek dosyada ayrıca açıklama yapmaya çalıştım.

[Tarkan VURAL]

Yeni konuya gerek yok, aynı sorunun laciverti. Konuları birleştirdim. Buradan takip edebilirsiniz.

Kod: Tümünü seç

Function KullanilanIzniEksilt(ByVal KullanilanIzin As Integer, _
                                ByVal DevredenIzin As Integer, _
                                ByVal HakEdilenIzin As Integer) As String
Dim toplamizinhakedis As Integer
toplamizinhakedis = DevredenIzin + HakEdilenIzin
Select Case KullanilanIzin
    Case Is > toplamizinhakedis
        KullanilanIzniEksilt = "Hakedişi geçiyor"
    Case Is = toplamizinhakedis
        KullanilanIzniEksilt = "= 0"
    Case Is < toplamizinhakedis
        If KullanilanIzin <= DevredenIzin Then
            KullanilanIzniEksilt = DevredenIzin - KullanilanIzin & " + " & HakEdilenIzin & " = " & _
                                    toplamizinhakedis - KullanilanIzin
        ElseIf KullanilanIzin > DevredenIzin And (KullanilanIzin - DevredenIzin < HakEdilenIzin) Then
            KullanilanIzniEksilt = "0 + " & toplamizinhakedis - KullanilanIzin & _
                                    " = " & toplamizinhakedis - KullanilanIzin
        End If
End Select
End Function

[düşünceli]

Elinize, beyninize, yüreğinize, emeğinize sağlık Tarkan Bey. Tam istediğim gibi olmuş. Çok teşekkür ederim.

[Tarkan VURAL]

Allah razı olsun. İstediğiniz gibi olmasına sevindim.

[düşünceli]

* Öncelikle Tarkan beye bu kod için teşekkür ediyorum.
B ve c sütunu ilgi satırlarında bulunan sayıların işlem adımlarıyla birlikte D sütunda toplamını gösteren bu koda tl ibaresi eklenmesi (örneğin: (155,00 ₺+ 251,00 ₺ = 406,00 ₺) gibi) ve sonucun (=406,00 ₺) dört işlemde (toplama-çıkarma-çarpma-bölme) kullanılabilmesi mümkün olabilir mi? (=e2+d2) gibi)

Kod: Tümünü seç

Function ToplaFormulGoster(ByVal ilksayi As Double, ByVal ikincisayi As Double) As String
ToplaFormulGoster = CStr(ilksayi) & " + " & CStr(ikincisayi) & " = " & CStr(ilksayi + ikincisayi)
End Function


[düşünceli]

Güncel...

[düşünceli]

Mutlu Yıllar

[düşünceli]

Güncel

[OmerFaruk72]

Kod: Tümünü seç

Function ToplaFormulGoster(ByVal ilksayi As Double, ByVal ikincisayi As Double, ByVal Para As Integer, ByVal Metod As Integer) As String

If Para < 0 Or Para > 2 Then
    MsgBox "Para hatalı tanımlanmış"
    ToplaFormulGoster = "Hata"
    GoTo Son
End If
If Metod < 0 Or Metod > 3 Then
    MsgBox "Metod hatalı tanımlanmış"
    ToplaFormulGoster = "Hata"
    GoTo Son
End If
Select Case Para
    Case 0
        PP = "TL"
    Case 1
        PP = "USD"
    Case 2
        PP = "EU"
End Select
Select Case Metod
    Case 0
        MM = " + "
    Case 1
        MM = " - "
    Case 2
        MM = " x "
    Case 3
        MM = " / "
End Select
ToplaFormulGoster = CStr(ilksayi) & PP & MM & CStr(ikincisayi) & PP & " = " & CStr(ilksayi + ikincisayi) & " " & PP
Son:
End Function

[Miraç CAN]

Elinize sağlık Ömer Faruk Bey,

Kullanışlılığı artırmak üzere "Hane" sayısı da eklesek,
Para birimi seçeneklerine simgelerini de dahil etsek,
Kullanım kolaylığı için "Hane", "Birim" ve "Metod" opsiyonel olsa,
Varsayılan olarak ta Hane sayısı "Sıfır", Birim "TL" ve Metod "Toplam" (+) ayarlarsak
Ve dört işlemin hepsine göre çalışsa; boş ise de hiçbir şey göstermese;
Diyerek güncellersek:

Kod: Tümünü seç

Function Dörtİşlem(ByVal ilksayi As Double, ByVal ikincisayi As Double, _
Optional ByVal Hane As Integer = 0, Optional ByVal Metod As Integer = 0, Optional ByVal Birim As Integer = 1) As String
If ilksayi Like 0 And ikincisayi Like 0 Then Dörtİşlem = "": GoTo çık
If Hane < 0 Then MsgBox "Hane sayısı geçersiz." & vbNewLine & "Pozitif tamsayı girin", _
            vbExclamation + vbOKOnly, "Dört İşlem Uyarı": Dörtİşlem = "Hata": GoTo çık
Select Case Birim
    Case 1:     Pb = "TL"
    Case 11:    Pb = ChrW(8378)
    Case 2:     Pb = "USD"
    Case 22:    Pb = "$"
    Case 3:     Pb = "EU"
    Case 33:    Pb = "€"
    Case Else: MsgBox "Para birim kodu tanımsız." & vbNewLine & "Fonksiyon yardımını kullanın", _
            vbExclamation + vbOKOnly, "Dört İşlem Uyarı": Dörtİşlem = "Hata": GoTo çık
End Select
Select Case Metod
    Case 0: Md = " + ": sonuç = ilksayi + ikincisayi
    Case 1: Md = " - ": sonuç = ilksayi - ikincisayi
    Case 2: Md = " x ": sonuç = ilksayi * ikincisayi
    Case 3: Md = " / ": sonuç = ilksayi / ikincisayi
    Case Else: MsgBox "Metod numarası geçersiz." & vbNewLine & "Fonksiyon yardımını kullanın", _
            vbExclamation + vbOKOnly, "Dört İşlem Uyarı": Dörtİşlem = "Hata": GoTo çık
End Select
Dörtİşlem = CStr(ilksayi) & Pb & Md & CStr(ikincisayi) & Pb & " = " & CStr(Round(sonuç, Hane)) & " " & Pb
çık:
End Function


Bir de fonksiyon yardımlarını eklersek:

Kod: Tümünü seç

Public Sub DefineFunction()
   Dim sFunctionName As String
   Dim sFunctionCategory As String
   Dim sFunctionDescription As String
   Dim aFunctionArguments() As String
   ReDim aFunctionArguments(1 To 5)
Fdesc = "Dört işlem formül göster" & vbNewLine & _
    "Verileri boş bırakırsanız varsayılan değerlere göre hesaplanır." & vbNewLine & _
    "Değerler bir tamsayı, başvurular bir hücre, bir formül ya da bir ad tanımı olabilir." & vbNewLine & _
    vbTab & "Yazan: Miraç CAN"
D1 = "İlk sayıyı girin." & vbNewLine & _
    "Değer bir tamsayı, başvurular bir hücre, bir formül ya da bir ad tanımı olabilir."
D2 = "İkinci sayıyı girin." & vbNewLine & _
    "Değer bir tamsayı, başvurular bir hücre, bir formül ya da bir ad tanımı olabilir."
D3 = "Virgülden sonra basamak sayıyı girin." & vbNewLine & _
    "Boş bırakılırsa varsayılan olarak ""0"" alınır."
D4 = "Metod numarasını girin." & vbNewLine & _
    "Boş bırakılırsa varsayılan olarak ""+"", ""Toplama"" işlemi alınır." & vbNewLine & _
    "0-Toplama, 1-Çıkarma, 2-Çarpma, 3-Bölme işlemini ifade eder."
D5 = "Para birimi kodunu girin." & "Boş bırakılırsa varsayılan olarak ""TL"" alınır." & vbNewLine & _
    "1-TL, 2-USD, 3-EU para birimini ifade eder." & vbNewLine & _
    "11-" & ChrW(8378) & ", 22-$, 33-€ para birimi simgelerini ifade eder."
   
   sFunctionName = "Dörtİşlem"
   sFunctionDescription = Fdesc
   sFunctionCategory = "Miraç CAN"
   aFunctionArguments(1) = D1
   aFunctionArguments(2) = D2
   aFunctionArguments(3) = D3
   aFunctionArguments(4) = D4
   aFunctionArguments(5) = D5

   Application.MacroOptions Macro:=sFunctionName, _
         Description:=sFunctionDescription, _
         Category:=sFunctionCategory, _
         ArgumentDescriptions:=aFunctionArguments
End Sub


Umarım azami fayda sağlanır.

[düşünceli]

Emeğinize sağlık.Teşekkür ederim.
Ben bu kodları çalıştıramadım.
Kodların birini modüle diğerini sayfa kaynağına kopyaladım başarılı olamayınca ters sırayla tekrar denedim lakin sonuç alamadım. Bir açıklama eklerseniz memnun olurum. İyi çalışmalar.

[Miraç CAN]

Emeğinize sağlık.Teşekkür ederim.
Ben bu kodları çalıştıramadım.
Kodların birini modüle diğerini sayfa kaynağına kopyaladım başarılı olamayınca ters sırayla tekrar denedim lakin sonuç alamadım. Bir açıklama eklerseniz memnun olurum. İyi çalışmalar.

ikisini de modüle, alt alta ekleyin.

[Miraç CAN]

Örnek dosya ektedir.

[düşünceli]

Örnek dosya ektedir.

Bu kadarını beklemiyordum doğrusu. Çok teşekkür ederim. İşimi fazlası ile görür. Binlik ayırıcı olarak, 00,00 ₺ (200,00 ₺ gibi) eklenebilirse dahada şık olur. Tabii bu benim düşüncem. Fikir olarak sundum. Elinize, yüreğnize, emeğinize sağlık. İyi çalışmalar.

[Miraç CAN]

Örnek dosya ektedir.

Bu kadarını beklemiyordum doğrusu. Çok teşekkür ederim. İşimi fazlası ile görür. Binlik ayırıcı olarak, 00,00 ₺ (200,00 ₺ gibi) eklenebilirse dahada şık olur. Tabii bu benim düşüncem. Fikir olarak sundum. Elinize, yüreğnize, emeğinize sağlık. İyi çalışmalar.

Güncellendi...

Kod: Tümünü seç

Function Dörtİşlem(ByVal ilksayi As Double, ByVal ikincisayi As Double, _
Optional ByVal Hane As Integer = 0, Optional ByVal Metod As Integer = 0, Optional ByVal Birim As Integer = 1) As String
If ilksayi Like 0 And ikincisayi Like 0 Then Dörtİşlem = "": GoTo çık
If Hane < 0 Then MsgBox "Hane sayısı geçersiz." & vbNewLine & "Pozitif tamsayı girin", _
            vbExclamation + vbOKOnly, "Dört İşlem Uyarı": Dörtİşlem = "Hata": GoTo çık
If Hane = 0 Then hn = "##,##0" Else hn = "##,##0." & Application.Rept(0, Hane)
Select Case Birim
    Case 1:     Pb = "TL"
    Case 11:    Pb = ChrW(8378)
    Case 2:     Pb = "USD"
    Case 22:    Pb = "$"
    Case 3:     Pb = "EU"
    Case 33:    Pb = "€"
    Case Else: MsgBox "Para birim kodu tanımsız." & vbNewLine & "Fonksiyon yardımını kullanın", _
            vbExclamation + vbOKOnly, "Dört İşlem Uyarı": Dörtİşlem = "Hata": GoTo çık
End Select
Select Case Metod
    Case 0: Md = " + ": sonuç = ilksayi + ikincisayi
    Case 1: Md = " - ": sonuç = ilksayi - ikincisayi
    Case 2: Md = " x ": sonuç = ilksayi * ikincisayi
    Case 3: Md = " / ": sonuç = ilksayi / ikincisayi
    Case Else: MsgBox "Metod numarası geçersiz." & vbNewLine & "Fonksiyon yardımını kullanın", _
            vbExclamation + vbOKOnly, "Dört İşlem Uyarı": Dörtİşlem = "Hata": GoTo çık
End Select
Dörtİşlem = CStr(Format(ilksayi, hn)) & Pb & Md & CStr(Format(ikincisayi, hn)) & Pb & " = " & CStr(Format(sonuç, hn)) & " " & Pb
çık:
End Function

[düşünceli]

Emeğinize sağlık. Süper oldu. Teşekkür ederim. Konuyu çözüldü olarak işaretleyebiliriz.