1 sayfadan 1. sayfa

Hücre Genişliğine Dokunmadan Otomotik Satır Yüksekliği Ayarl

İletiTarih: 19 Kas 2020 22:10
Levent145
A3 G3 ve
A4 G4 aralığında olmak üzere birleştirilmiş hücrelerim var
Bazen yazılar fazla olduğunda satırın içinde görünmüyor
Satır genişliği sabit kalsın dokunulmadan
Hücreye girilen metin ikinci üçüncü dördüncü beşinci satıra sattığında satır yüksekliği otomotik açılsın veya satır sayısına göre otomotik yükseklik düşsün
Böyle hazır bir koda ihtiyacım var

Cevap: Hücre Genişliğine Dokunmadan Otomotik Satır Yüksekliğ

İletiTarih: 20 Kas 2020 00:02
Erkan Akayay
Sayfa koduna kopyalayın.

Kod: Tümünü seç
Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("A3", "A4")) Is Nothing Then Exit Sub
Dim birlesik_genislik As Single
Dim hucre As Range
Dim alan As Range
Dim sutun_genislik As Double
Dim yukseklik As Double
    Application.ScreenUpdating = False
    On Error Resume Next
    Set alan = Range(Range(Target.Address).MergeArea.Address)
    With alan
      .MergeCells = False
      sutun_genislik = .Cells(1).ColumnWidth
      birlesik_genislik = 0
      For Each hucre In alan
          hucre.WrapText = True
          birlesik_genislik = hucre.ColumnWidth + birlesik_genislik
      Next
      birlesik_genislik = birlesik_genislik + alan.Cells.Count * 0.66
      .Cells(1).ColumnWidth = birlesik_genislik
      .EntireRow.AutoFit
      yukseklik = .RowHeight
      .Cells(1).ColumnWidth = sutun_genislik
      .MergeCells = True
      .RowHeight = yukseklik
    End With
    Application.ScreenUpdating = True
End Sub

Cevap: Hücre Genişliğine Dokunmadan Otomotik Satır Yüksekliğ

İletiTarih: 20 Kas 2020 13:04
Levent145
Çok teşekkür ederim. Kodlar çalıştı. Elinize emeğinize sağlık