[rn_qwerty]

VBA, çoğu kontrolün hwnd bilgisini vermez. Bazı kontrollerin hWnd bilgisini bulmak için aşağıdaki kodları kullanabilirsiniz.
Örnek: hWnd=GetHWND(UserForm1.Frame1) veya hWnd=GetHWND(UserForm1.ListView1) gibi.

Kod: Tümünü seç

Public Declare Function apiGetFocus Lib "user32" Alias "GetFocus" () As Long

Public Function GetHWND(objCtl As Control) As Long
    On Error Resume Next
    objCtl.SetFocus
    If Err Then
        GetHWND = 0
    Else
        GetHWND = apiGetFocus
    End If
    On Error GoTo 0
End Function



Not: Tüm kontroller için geçerli değildir.

[Enes Recep BAĞ]

Remzi Bey

[Erhan Yavuz]

İşlenmemiş bir konuydu, bilgilendirme için teşekkürler..

[Murat OSMA]

Bu konuda benim de önceden yabancı kaynaktan arşivime aldığım bir dosya mevcut.
Açık olan tüm pencerelerin, nesnelerin hWnd (handle id)'sini bulabilirsiniz.

[Erhan Yavuz]

Murat sağolasın..

[sinanplater]

HWnd değişkeni pencere referansıdır. Yıllar önce Bill Gates amcamız Windows'un arabirimini tasarlarken arabirimi oluşturan her küçük pencereye bir numara vermeyi ve pencereleri numaralarıyla adlandırmayı düşünmüş. İşletim sisteminiz proje her çağrıldığında HWnd değişkenine bir tam sayı atar. Her zaman değişken olan bu tam sayı herhangi bir kontrol veya pencerenin referansını belirtir. Bu referans değişkendir çünkü çalıştırılan diğer uygulamalar ve yüklenen kontroller zaten kendilerine birer HWnd değeri alır.

Bir nesnenin HWnd değerini öğrenmek için X = nesne.hWnd gibi bir ifade kullanabilir X değerini öğrenerek Hwnd değerini okuyabilirsiniz.

Kod: Tümünü seç

Option Explicit
 
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" _
(ByVal hWnd1 As Long, ByVal hWnd2 As Long, ByVal lpsz1 As String, ByVal lpsz2 As String) As Long
Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" _
(ByVal hWnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long
Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" _
(ByVal hWnd As Long, ByVal lpString As String, ByVal cch As Long) As Long
 
Private x As Integer
 
Private Type winEnum
    winHandle As Integer
    winClass As Integer
    winTitle As Integer
    winHandleClass As Integer
    winHandleTitle As Integer
    winHandleClassTitle As Integer
End Type
Dim winOutputType As winEnum


Kod: Tümünü seç

Public Sub GetWindows()
    x = 0
    winOutputType.winHandle = 0
    winOutputType.winClass = 1
    winOutputType.winTitle = 2
    winOutputType.winHandleClass = 3
    winOutputType.winHandleTitle = 4
    winOutputType.winHandleClassTitle = 5

    GetWinInfo 0&, 0, winOutputType.winHandleClassTitle
End Sub

Kod: Tümünü seç

Private Sub GetWinInfo(hParent As Long, intOffset As Integer, OutputType As Integer)
   
    Dim hWnd As Long, lngRet As Long, y As Integer
    Dim strText As String
    hWnd = FindWindowEx(hParent, 0&, vbNullString, vbNullString)
    While hWnd <> 0
        Select Case OutputType
        Case winOutputType.winClass
            strText = String$(100, Chr$(0))
            lngRet = GetClassName(hWnd, strText, 100)
            Range("a1").Offset(x, intOffset) = Left$(strText, lngRet)
        Case winOutputType.winHandle
            Range("a1").Offset(x, intOffset) = hWnd
        Case winOutputType.winTitle
            strText = String$(100, Chr$(0))
            lngRet = GetWindowText(hWnd, strText, 100)
            If lngRet > 0 Then
                Range("a1").Offset(x, intOffset) = Left$(strText, lngRet)
            Else
                Range("a1").Offset(x, intOffset) = "N/A"
            End If
        Case winOutputType.winHandleClass
            Range("a1").Offset(x, intOffset) = hWnd
            strText = String$(100, Chr$(0))
            lngRet = GetClassName(hWnd, strText, 100)
            Range("a1").Offset(x, intOffset + 1) = Left$(strText, lngRet)
        Case winOutputType.winHandleTitle
            Range("a1").Offset(x, intOffset) = hWnd
            strText = String$(100, Chr$(0))
            lngRet = GetWindowText(hWnd, strText, 100)
            If lngRet > 0 Then
                Range("a1").Offset(x, intOffset + 1) = Left$(strText, lngRet)
            Else
                Range("a1").Offset(x, intOffset + 1) = "N/A"
            End If
        Case winOutputType.winHandleClassTitle
            Range("a1").Offset(x, intOffset) = hWnd
            strText = String$(100, Chr$(0))
            lngRet = GetClassName(hWnd, strText, 100)
            Range("a1").Offset(x, intOffset + 1) = Left$(strText, lngRet)
            strText = String$(100, Chr$(0))
            lngRet = GetWindowText(hWnd, strText, 100)
            If lngRet > 0 Then
                Range("a1").Offset(x, intOffset + 2) = Left$(strText, lngRet)
            Else
                Range("a1").Offset(x, intOffset + 2) = "N/A"
            End If
        End Select
         'check for children
        y = x
        Select Case OutputType
        Case Is > 4
            GetWinInfo hWnd, intOffset + 3, OutputType
        Case Is > 2
            GetWinInfo hWnd, intOffset + 2, OutputType
        Case Else
            GetWinInfo hWnd, intOffset + 1, OutputType
        End Select
         'increment by 1 row if no children found
        If y = x Then
            x = x + 1
        End If
         'now get next window
        hWnd = FindWindowEx(hParent, hWnd, vbNullString, vbNullString)
    Wend
     
End Sub


[Tarkan VURAL]

Peki handle id numarasını bildiğimiz bir pencerenin üzerinde bulunan kontrollerinin isimlerini bulabilir miyiz ?

[chngrcn]

Peki handle id numarasını bildiğimiz bir pencerenin üzerinde bulunan kontrollerinin isimlerini bulabilir miyiz ?

Tarkan hocamın sorusunu bende tekrar etmek istiyorum..

handle id numarasını bildiğimiz bir pencerenin üzerinde bulunan kontrollerinin isimlerini, başlıklarını, HANDLE numaralarını bulabilir miyiz ?

örneğin Userform üzerinde bir kaç objemiz var,

textbox1.handle
combobox1.handle
listbox1.handle
checkbox1.handle
commandbutton1.handle
optionbutton1.handle gibi nesnelerin handle referans değerlerini nasıl bulabiliriz ?

(not: sadece userform için değil, windows altında çalışan diğer uygulamalar altındaki text kutuları içinde geçerli bir kodlama varmıdır ? ) MESELA MASA ÜSTÜNDE AKTİF OLAN HERHANGİ BİR PENCERE İÇERİSİNDEKİ TEXTBOXLARIN HANDLE NUMARASI NASIL BULUNUR.

şimdiden teşekkür ederim.. yardımlarınızı rica ederim.

[Erkan Akayay]

İsimsiz kullanıcılar grubuna destek verilmemektedir. Profilinizi güncelledikten sonra bilgi verilecektir.