kısmı arama yapmak

[hhd001]

Merhaba
A sutunda 1 Ali DEMİ şeklinde veriler var
asagıdakı kod ile Textboxa veri girince listbox da A sutunundaki verileri listeleme yapıyorum. Fakat sadece ilk harfe gore listeleme oluyor.
1 yazınca sadece 1 ile başlayanlar cıkıyor. Ali yazdıgımda herhangi bir veri gelmiyor. Ben DE yazdıgımda içerisinde DE olan satırları nasıl listeleyebilirim.

Kod: Tümünü seç

Private Sub TextBox6_Change()
Dim sf As Worksheet
Set sf = Sheets("Sayfa1")
ListBox1.RowSource = ""
ListBox1.Clear
For i = 1 To Range("a65536").End(3).Row
   If sf.Range("A" & i) Like TextBox6.Value & "*" Then 'A sütununda arama yapar.
    ListBox1.AddItem
    ListBox1.List(ListBox1.ListCount - 1, 0) = sf.Range("A" & i)

   End If
Next i
End Sub

[SNNAY]

Deneyiniz;

Kod: Tümünü seç

Private Sub TextBox6_Change()
    Dim sf As Worksheet
    Set sf = Sheets("Sayfa1")
    ListBox1.Clear

    If Trim(TextBox6.Value) = "" Then Exit Sub ' TextBox boşsa çık

    Dim i As Long
    For i = 1 To sf.Cells(sf.Rows.Count, "A").End(xlUp).Row
        If LCase(sf.Range("A" & i).Value) Like "*" & LCase(TextBox6.Value) & "*" Then
            ListBox1.AddItem
            ListBox1.List(ListBox1.ListCount - 1, 0) = sf.Range("A" & i).Value
        End If
    Next i
End Sub